*     BYMAIL.WS     -WordStar PROGRAM
STORE 0 TO MQ:CT
STORE '                                                                  '  TO MQ:SLCT
STORE  'Y'  TO MQ:ANS
STORE  '        '  TO MQ:WDAT
DO WHILE MQ:WDAT =  '      '
 @ 21,10 SAY  ' NAME OF DATA FILE FOR WordStar '  GET MQ:WDAT
 READ
ENDDO
@ 21,10
@ 21,10 SAY  ' DO YOU WISH TO dSCAN?  ' GET MQ:ANS
READ
IF !(MQ:ANS)= 'Y'
 @ 21,10
 @ 21,10 SAY  ' PLEASE ENTER SELECTION CRITERIA '
 @ 23,10 GET MQ:SLCT
 READ
 @ 23,10
ELSE
 STORE  ' T '  TO MQ:SLCT
ENDIF
@ 23,10
STORE TRIM(MQ:WDAT) TO MQ:WDAT
STORE MQ:WDAT+'.DOC'  TO MQ:WDOC
STORE MQ:WDAT+'.DAT'  TO MQ:WDAT
@ 22,10 SAY  ' CREATING DOCUMENT FILE:  '+MQ:WDOC
SET CONSOLE OFF
SET ALTERNATE TO &MQ:WDOC
SET ALTERNATE ON
?'.OP'
?'.DF '+MQ:WDAT
?'.RV '+' first, last, company, address, city, st, zip, home, work, comments'
SET ALTERNATE OFF
SET CONSOLE ON
@ 23,10 SAY  ' CREATING DATA FILE:  '+MQ:WDAT
SET CONSOLE OFF
SET ALTERNATE TO &MQ:WDAT
SET ALTERNATE ON
GOTO TOP
* REPEAT UNTIL FILE ENDS
DO WHILE .NOT. EOF
 IF &MQ:SLCT
 STORE MQ:CT+1 TO MQ:CT
 ? 
 ??  CHR(34)+ TRIM(first) +CHR(34) +','
 ??  CHR(34)+ TRIM(last) +CHR(34) +','
 ??  CHR(34)+ TRIM(company) +CHR(34) +','
 ??  CHR(34)+ TRIM(address) +CHR(34) +','
 ??  CHR(34)+ TRIM(city) +CHR(34) +','
 ??  CHR(34)+ TRIM(st) +CHR(34) +','
 ??  CHR(34)+ TRIM(zip) +CHR(34) +','
 ??  CHR(34)+ TRIM(home) +CHR(34) +','
 ??  CHR(34)+ TRIM(work) +CHR(34) +','
 ??  CHR(34)+ TRIM(comments) +CHR(34)
 ENDIF
 SKIP
ENDDO
SET CONSOLE ON
@ 21,10
@ 22,10
@ 23,10
@ 23,10 SAY STR(MQ:CT,4)+  ' RECORDS WERE PLACED INTO DATA FILE '
GOTO TOP
SET ALTERNATE OFF
RELEASE MQ:WDAT,MQ:WDOC,MQ:ANS,MQ:SLCT,MQ:CT